nix

stagit.nix (5807B)

---

 {
   config,
   lib,
   pkgs,
   configData,
   haravara,
   ...
 }: let
   cfg = config.services.haravara.stagit;
 
   gitoliteUser = config.services.gitolite.user;
   reposDir = "${config.services.gitolite.dataDir}/repositories";
   assets = "${pkgs.stagit}/share/doc/stagit";
 
   excludeNames = ["gitolite-admin"] ++ cfg.excludeRepos;
   excludeDirPattern = lib.concatMapStringsSep "|" (r: "${r}.git") excludeNames;
   excludeNamePattern = lib.concatStringsSep "|" excludeNames;
 
   applyRepoMeta = lib.concatStrings (lib.mapAttrsToList (name: meta: ''
       if [ -d "${reposDir}/${name}.git" ]; then
         ${lib.optionalString (meta.description != null) ''
         printf '%s' ${lib.escapeShellArg meta.description} > "${reposDir}/${name}.git/description"
       ''}
         ${lib.optionalString (meta.owner != null) ''
         git -C "${reposDir}/${name}.git" config gitweb.owner ${lib.escapeShellArg meta.owner}
       ''}
       fi
     '')
     cfg.repos);
 
   preamble = ''
     export LC_CTYPE="C.UTF-8"
     umask 022
 
     reposdir="${reposDir}"
     htmldir="${cfg.htmlDir}"
     cloneurl="ssh://${gitoliteUser}@${cfg.domain}:${toString cfg.sshPort}"
 
     mkdir -p "$htmldir"
     install -m644 "${assets}/style.css" "$htmldir/style.css"
     # Hide owner field as i am the only user
     echo '#index tr > *:nth-child(3) { display: none; }' >> "$htmldir/style.css"
     install -m644 "${../mixins/stagit/fred.png}" "$htmldir/logo.png"
     install -m644 "${../mixins/stagit/fred.png}" "$htmldir/favicon.png"
 
     set --
     for dir in "$reposdir"/*.git; do
       [ -d "$dir" ] || continue
       case "$(basename "$dir")" in ${excludeDirPattern}) continue ;; esac
       set -- "$@" "$dir"
     done
   '';
 
   render_repo = ''
     render_repo() {
       dir="$1"
       d=$(basename "$dir" .git)
       mkdir -p "$htmldir/$d"
       (
         cd "$htmldir/$d" || exit 1
         stagit -c .cache -u "$cloneurl/$d" "$dir"
         ln -sf log.html index.html
         ln -sf ../style.css style.css
         ln -sf ../logo.png logo.png
         ln -sf ../favicon.png favicon.png
       ) || echo "stagit: failed to render $d" >&2
     }
   '';
 
   generate = pkgs.writeShellApplication {
     name = "stagit-generate";
     runtimeInputs = [pkgs.stagit pkgs.git pkgs.coreutils];
     text = ''
       ${preamble}
       ${applyRepoMeta}
       ${render_repo}
 
       stagit-index "$@" > "$htmldir/index.html"
       for dir in "$@"; do
         render_repo "$dir"
       done
     '';
   };
 
   postReceive = pkgs.writeShellApplication {
     name = "post-receive";
     runtimeInputs = [pkgs.stagit pkgs.git pkgs.coreutils];
     text = ''
       ${preamble}
       ${applyRepoMeta}
       ${render_repo}
 
       name=$(basename "$(pwd)")
       d=$(basename "$name" .git)
       case "$d" in ${excludeNamePattern}) exit 0 ;; esac
 
       # Detect a force-push so the commit cache can be rebuilt from scratch.
       force=0
       while read -r old new _ref; do
         [ "$old" = "0000000000000000000000000000000000000000" ] && continue
         [ "$new" = "0000000000000000000000000000000000000000" ] && continue
         if [ -n "$(git rev-list "$old" "^$new" 2>/dev/null | sed 1q)" ]; then
           force=1
           break
         fi
       done
 
       if [ "$force" = "1" ]; then
         rm -f "$htmldir/$d/.cache"
         rm -rf "$htmldir/$d/commit"
       fi
 
       render_repo "$reposdir/$name"
       stagit-index "$@" > "$htmldir/index.html"
     '';
   };
 in {
   options.services.haravara.stagit = {
     enable = lib.mkEnableOption "stagit static git pages backed by gitolite";
 
     domain = lib.mkOption {
       type = lib.types.str;
     };
 
     htmlDir = lib.mkOption {
       type = lib.types.str;
       default = "/var/lib/stagit";
     };
 
     sshPort = lib.mkOption {
       type = lib.types.port;
       default = 22;
     };
 
     authLabel = haravara.authLabelOption;
 
     excludeRepos = lib.mkOption {
       type = lib.types.listOf lib.types.str;
       default = [];
       example = ["admin" "internal"];
     };
 
     repos = lib.mkOption {
       default = {};
       type = lib.types.attrsOf (lib.types.submodule {
         options = {
           description = lib.mkOption {
             type = lib.types.nullOr lib.types.str;
             default = null;
           };
           owner = lib.mkOption {
             type = lib.types.nullOr lib.types.str;
             default = null;
           };
         };
       });
     };
 
     adminPubkey = lib.mkOption {
       type = lib.types.str;
       default = builtins.head configData.users.${configData.defaultUser}.authorizedKeys;
     };
   };
 
   config = lib.mkIf cfg.enable {
     services = {
       gitolite = {
         enable = true;
         inherit (cfg) adminPubkey;
         commonHooks = ["${postReceive}/bin/post-receive"];
       };
 
       openssh.settings.AllowUsers = [gitoliteUser];
 
       caddy.virtualHosts."${cfg.domain}".extraConfig = ''
         ${haravara.mkAuthImport cfg.authLabel}
         root * ${cfg.htmlDir}
         encode gzip
         file_server
       '';
     };
 
     systemd = {
       tmpfiles.rules = [
         "d ${cfg.htmlDir} 0755 ${gitoliteUser} ${config.services.gitolite.group} -"
       ];
 
       services.stagit-generate = {
         description = "Generate stagit static pages for all gitolite repos";
         after = ["gitolite-init.service"];
         wants = ["gitolite-init.service"];
         wantedBy = ["multi-user.target"];
         serviceConfig = {
           Type = "oneshot";
           User = gitoliteUser;
           Group = config.services.gitolite.group;
           ExecStart = "${generate}/bin/stagit-generate";
         };
       };
 
       timers.stagit-generate = {
         description = "Periodic stagit regeneration";
         wantedBy = ["timers.target"];
         timerConfig = {
           OnCalendar = "*:0/30";
           Persistent = true;
         };
       };
     };
   };
 }